13.6. Tcl Drivers

mvlcgenerate supports user written drivers in Tcl as well as C++. These can be significatly easier to write. In this section, the general requirements of a Tcl driver are described. Subsections walk through a Sample Tcl driver with the same functionality as the Sample C++ driver in the previous section, and document support facilities available to Tcl drivers.

Tcl drivers must be Tcl command ensembles. A commane ensemble, is simple a command with subcommands. In the core Tcl language itself, the file is an example of a command ensemble.

Tcl provides many ways to produce command ensembles. Since a driver may need to support many instances of its hardware, the best mapping to that need is one of the Tcl Object oriented packages such as snit, Incremental Tcl, or TclOO.

Object oriented extensions to Tcl have the common property that a class can be thought of as a thing that generates command ensembles. The base command represents a class instance (object), and its subcommands, the object's methods as defined by its class code.

Typically driver instances will need to be configured. At the very least, real drivers will need to have their instances told the base address of the device hardware the instance is generating code for. Snit and incremental Tcl are, therefore good matches as both provide their objects with built in configure and cget subcommands and provide a mechanism for easily defining configurable options.

Any driver class must implement three methods in addition to any others it chooses:

package require snit        


snit::type SampleDriver {   
    
    option -marker -default 0
    option -resetloc
    option -resetvalue -default 0xaaaa    
    option -writeendrun -default false
    option -endrunloc
    option -endrunvalue -default 0xbbbb

    
    constructor args {
        $self configurelist $args      
    }

    
    method Initialize vme {           
        $vme vmeWrite16 $options(-resetloc) \
        $::CVMUSBReadoutList::a32UserData $options(-resetvalue)
    }
    
    method addReadoutList list {     
        $list addMarker  $options(-marker)
    }

    
    method onEndRun vme {           
        if {$options(-writeendrun)} {
            $vme vmeWrite16 $options(-endrunloc) \
                $::CVMUSBReadoutList::a32UserData $options(-endrunvalue)
        }
    }
}